Commande automatique d'une caméra semi-immergée

Introduction
 Quelle soit manuelle, automatique, à télécommande filaire ou radiocommandée, la photo/vidéo semi-immergée nécessite un caisson étanche pour le matériel.
Un point important dans la réalisation est la transparence de la fenêtre devant l'objectif. Elle doit être exempte de défaut et antireflet de préférence.
Il faut également réfléchir à la ligne de flottaison en prévoyant de pouvoir lester le caisson si nécessaire car le poids de la batterie ne suffit pas toujours.
Un réglage de la position de la caméra permet quant à lui de filmer tant hors de l'eau que sous l'eau.
L'utilisation d'une ''dashcam'' (caméra pour tableau de bord automobile) ou ''car dvr'' (car digital video recorder) facilite la prise de vue rapide.
En plus de sa résolution HD (1920x1080), le principal avantage d’une dashcam dans ce type d’application est sa rapidité à entrer en action car elle commence à enregistrer automatiquement moins de 3 secondes après sa mise sous tension.
D'autre part sa focale fixe présente des avantages souvent recherchés par les photographes (qualité, ouverture, poids, prix...)

Réalisation

Le modèle de ''Car DVR'' que j'ai utilisé ne permet pas de filmer la nuit sans apport de lumière, ni en infrarouge.
C'est la raison pour laquelle une photocellule LDR et un réglage du seuil de luminosité minimum inhibent toute prise de vue en cas de clarté insuffisante.
La dashcam possède une batterie interne et la fiche prévue pour l’allume-cigare contient un circuit électronique adaptateur qu’il ne faut pas dissocier de la caméra lorsqu’on l’alimente à partir d’une batterie externe de 12 Volts.
La LED ''en service'' n'est utile que pendant l'installation et le pontage J1 permet de la désactiver.
La mesure de lumière ambiante et la prise de vue automatique sont gérées par un PIC (Programmable Integrated Circuit) de type PICAXE 08M2.

Installation
La détection de présence animale est réalisée par un ''PIR Sensor'' (passive infrared sensor).  
Ce détecteur est équipé de 2 potentiomètres de réglage :  la durée de l'impulsion de sortie et la sensibilité du détecteur.
La durée de l'impulsion délivrée influence peu le fonctionnement du système de prise de vue automatique.
Pour sa part, la sensibilité du détecteur doit être réglée empiriquement.
L'utilisation d'une fourche et le réglage en hauteur de la fixation empêchent le déplacement latéral du caisson.
Il est également important que celui-ci conserve le mieux possible son assiette horizontale malgré les ondulations de l'eau et les changements de niveaux.
C'est le rôle de l'articulation à 2 charnières qui relie la fourche d'ancrage à l'équerre du caisson. Les mouvements sont semblables à ceux d'un bateau.
 

Programme du PICAXE 08M2
  
Symbol Record_Time=60                ; Durée d'enregistrement (en Sec.)

Symbol Light_Measure=b27
Symbol Seuil_Consigne=b23
Symbol Seuil_Haut=b25
Symbol Seuil_Bas=b24

let dirsC=%010001                          ; configure le Port C
low C.0                                           ; Caméra hors tension
low C.4                                           ; LED "en service" éteinte


main:

  let time=0
 
  readadc C.2,Seuil_Consigne                        ; Mesure Consigne "Seuil de luminosité"
  readadc C.1,b26                                          ; Mesure INVERSE de la luminosité ambiante
  Light_Measure=255-b26                               ; Inversion de la pente de la courbe
  Seuil_Haut=Seuil_Consigne+8 MAX 255
  Seuil_Bas=Seuil_Consigne-8 MIN 0
 
  if Light_Measure<Seuil_Bas then                  ; si luminosité insuffisante (Tension LDR élevée)
      low C.4                                                   ; Eteindre la LED "en service"
      low C.0                                                   ; Arrêt de la caméra
      goto main
  endif
  if Light_Measure>Seuil_HAUT then              ; si luminosité suffisante (Tension LDR basse)
      high C.4                                                 ; Allumer la LED "en service"
      if pinC.3 = 0 then                                    ; si aucune détection de présence
          goto main
      endif
      high C.0                                                 ; Mise sous tension de la caméra et enregistrement
      let time=0
    boucle:
      if time<Record_Time then                        ; si temps d'enregistrement non écoulé
        if pinC.3 = 1 then                                  ; si présence encore détectée
            let time=0                                        ; alors prolongement de l'enregistrement
        endif
          goto boucle
      endif
      low C.0                                                 ; Arrêt de la caméra
  endif
 
goto main



Sur ce blog, un article similaire développe la réalisation d'un ''Faux tronc d'arbre pour caméra animalière''